RAP Search Help and Additional Bindings

Published: November 2025

How to add search help to RAP field? The details will be covered below.

Source Data of Search Help

In SAP ABAP RAP, value help (also known as search help) can be sourced from various types of data providers—not just CDS views or DDIC domains. However, the discussion below will focus on only two of these options.

Steps For Adding Search Help

Steps for using domain as search help are explanin as follow:

Working with Domain Values in CDS

The first step is to verify whether the domain required for the field is available. If the domain exists, you can proceed with it. Ensure that the domain contains fixed values that are correctly maintained.

Next, create a CDS entity to expose and display the fixed domain values. For this purpose, use the special CDS view entity DDCDS_CUSTOMER_DOMAIN_VALUE_T and pass the domain name through the parameter p_domain_name. To handle language-related behavior, apply the annotation @Semantics.language: true wherever necessary.

Complete CDS Definition

		
		@AbapCatalog.viewEnhancementCategory: [#NONE]
		@AccessControl.authorizationCheck: #NOT_REQUIRED
		@EndUserText.label: 'Gender Domain'
		@Metadata.ignorePropagatedAnnotations: true
		@ObjectModel.usageType:{
			serviceQuality: #X,
			sizeCategory: #S,
			dataClass: #MIXED
		}
		define view entity ZI_GENDER_BD 
			as select from DDCDS_CUSTOMER_DOMAIN_VALUE_T( p_domain_name:  'ZDOM_GENDER')
		{
			key domain_name,
			key value_position,
			@Semantics.language: true
			key language,
			value_low as Value,
			@Semantics.text: true
			text as Description
		}

Activate the CDS view entity, and you’re done. When previewing the data, all domain values will be displayed.

To use the generated CDS View Entity within the target interface CDS View Entity, you must incorporate the previously created CDS View Entity by adding it as an association:

		
		association [1..1] to ZI_GENDER_BD as _gender 
			on $projection.Gender = _gender.Value

Next, include the association as fields (this can be placed after the last field):

		
		_gender,
		_gender.Description as Genderdesc

Finally, add the required annotation to the field as follows:

		
		@Consumption.valueHelpDefinition: [{
			entity: { 
				name: 'ZI_GENDER_BD', 
				element: 'Value' 
			},
			distinctValues: true,
			additionalBinding: [{
				localElement: 'Genderdesc',
				element: 'Description',
				usage: #FILTER_AND_RESULT
			}]
		}]
		Gender;
		

		@UI: {  identification: [{ position: 85, label: '' }] }
		Genderdesc;